CU Amiga Super CD-ROM 2/CU Amiga Magazine's Super CD-ROM 02 (1996)(EMAP Images)(GB)[!][issue 1996-04].iso/magazine/amiga_e/amigae.jan.archive/000022_nkraft_Sun, 9 Jan 94 22:48:56 PST.msg

Text File | 1994-02-17 | 10KB | 243 lines

Received: by bkhouse.cts.com (V1.16/Amiga)
    id AA00000; Sun, 9 Jan 94 22:48:56 PST
Date: Sun, 9 Jan 94 22:48:56 PST
Message-Id: <[e-mail]>
X-Mailer: //\\miga Electronic Mail (AmiElm 2.253)
Organization: Argus Computing, San Diego, CA
Reply-To: [e-mail]
From: [e-mail] (Norman R. Kraft)
To:
Subject: ADMIN: Lost Mail

Due to some problems with my feed system, several (four,
I think) incoming mailings destined for the amigae list
were lost before making it to the list. There were really
very few of these, so wait around a day or two and if
you don't see your mail on the list, try resending it.

Sorry for the inconvenience.

Norm.


----------------------------------------------------------------------------
Norman Kraft                            INET  : [e-mail] (work)
Peptide-T Clinical Trial                or try: [e-mail] (home)
HIV Neurobehavioral Research Center     UUCP  : ucsd!nkraft
Dept of Psychiatry, School of Medicine
University of California, San Diego          Usual disclaimers...
----------------------------------------------------------------------------
From crash!comlab.oxford.ac.uk!ecs.oxford.ac.uk!m88jrh Mon, 10 Jan 94 02:11:04 PST
Received: by bkhouse.cts.com (V1.16/Amiga)
    id AA00000; Mon, 10 Jan 94 02:11:04 PST
Received: from sun2.nsfnet-relay.ac.uk by crash.cts.com with smtp
    (Smail3.1.28.1 #18) id m0pJIUh-0000L5C; Mon, 10 Jan 94 01:01 PST
Received: from ecs.oxford.ac.uk (ecs.ecs) by comlab.oxford.ac.uk id AA10716;
          Mon, 10 Jan 94 09:00:06 GMT
Received: from ecs.ox.ac.uk (booth6.ecs) by ecs.oxford.ac.uk (4.1/ecs.1)
          id AA24506; Mon, 10 Jan 94 09:02:36 GMT
Received: by ecs.ox.ac.uk (4.1/ecs2.0) id AA00275; Mon, 10 Jan 94 09:01:13 GMT
Via: uk.ac.oxford.comlab; Mon, 10 Jan 1994 09:00:17 +0000
Date: Mon, 10 Jan 94 09:01:13 GMT
Message-Id: <[e-mail]>
From: [e-mail]
To: [e-mail]
Subject: SetFunction and calling E code


Some time ago I was trying to get SetFunction() to work from E.  I tried all
kinds of things (and not very many of them were sensible).  Recently I asked
Wouter if he could give me an example of how to use CreateNewProc() from E
and he came up with a lovely little example (albeit using AddTask()).  Then
everything fell into place and I realised what I'd been doing wrong.  The
following example program shows, I think, how you should do it.

So, to the vital clue:  to use an E procedure from another task you need
some way of setting register A4 to the correct value.  The simplest way is
to use self-modifying code (yuk!), as in the example below where "store" is
used.  The procedure (or labelled code) which is run from a different task
must reinstate A4 to the stored value before it can use any E variables.  Of
course, you can save things on the stack before changing A4 if you need to.

Now the example: this behaves a bit like SnoopDos, monitoring calls to
OpenLibrary() (in exec.library).  It uses the SetFunction() call to run
a piece of E code instead of the normal OpenLibrary() code.  There are
several points worth mentioning:

1) Self-modifying code in two places: "store" and "patch".  This means this
   program might not work properly on machines with large instruction caches
   (it works OK on my A1200, though).  I'd like to know if someone can get
   rid of the "patch" kludge --- the "store" stuff is respectable in
   comparison.  BTW, the "JMP (A0)" kind of thing didn't work...
2) Use of a message port to enable some visible output.  Because I'm lazy I
   used the Release 2 (and above) CreateMsgPort()/DeleteMsgPort() calls.
   (Will E v3.0 have an amiga.m module like C's amiga.lib?)
   This is a *very* important point: because our patched routine might not
   be run by a process we cannot use any dos.library calls.  However, we
   can send a message to the process that did the patch and tell it what to
   print!
3) Moving on to the patched routine (labelled "newf"), the first thing that
   is done is preserving all the registers.  We don't want to muck up the
   arguments that were sent to the OpenLibrary() call.
4) Luckily, the call to sendmsg() from the patched routine seems to
   preserve A1, which is what we are interested in. (Wouter, what registers
   can we rely on being preserved?)
5) sendmsg() works out the name of the task that is running it and sends
   this name and the name of the library in a message.
6) Back in main(), the patching process is waiting for a CTRL-C from the
   user or a message on its (private) port.  Any messages received are
   processed and printed nicely (!).
7) The first Disable() call is necessary. The second is probably not (call
   me paranoid if you will).  I think the PutMsg() does not need wrapping
   in Disable()/Enable() (or Forbid()/Permit()) because we know the port
   isn't going away...
8) The New() call from the patched routine seems to work.  And the memory
   seems to be added to the patching routine's memory list and freed when
   it terminates.  All the same I threw in some Dispose[Link]()'s (in
   printmsgs()) to allow some re-use of memory whilst it's running).
9) Using SetFunction() can never be 100% reliable so don't do it ;-)
   What this means is: don't expect something like this to work if you have
   another program messing with the library...

Well, I hope this is correct and (or?) helpful...


----------------------  CUT HERE ------------------------------------------
/* setf.e -- a SnoopDos-like program to monitor calls to OpenLibrary() */

OPT OSVERSION=37

MODULE 'dos/dos', 'exec/ports', 'exec/tasks', 'exec/nodes'

CONST OFFSET=$fdd8  /* execbase offset of OpenLibrary() */

/* "mymsg" must begin with the standard message object "mn", followed by
   any kind of data (in this case, two pointers [to strings]).
*/
OBJECT mymsg
  msg:mn
  s, t
ENDOBJECT

/* "port" will be used from the patched routine, too, so it's global */
DEF port:PTR TO mp

/* You can change the library function to be patched by changing OFFSET
   and the "execbase" in the *two* calls to SetFunction().  If you want to
   patch a library other than dos, exec, graphics and intuition you need
   to OpenLibrary() it first.
   (Note: some [old?] libraries cannot be patched in this way.  Also, some
   functions in some libraries can't be patched like this either!  Even the
   RKRM's aren't too clear about this...)
*/
PROC main()
  DEF ps, us, addr, loop, sig, oldf
  IF port:=CreateMsgPort()
    Disable()     /* Don't let anyone mess things up... */
    IF oldf:=SetFunction(execbase, OFFSET, {newf})
      addr:={patch}+2
      ^addr:=oldf
      Enable()    /* Now we can let everyone else back in */
      LEA store(PC), A0
      MOVE.L A4, (A0)    /* Store the A4 register... */
      ps:=Shl(1,port.sigbit)   /* Set up port and user signal bits */
      us:=SIGBREAKF_CTRL_C
      loop:=TRUE
      WHILE loop
        sig:=Wait(ps OR us)
        IF sig AND ps
          printmsgs()
        ENDIF
        IF sig AND us
          loop:=FALSE
        ENDIF
      ENDWHILE
      Disable()   /* Paranoid... */
      SetFunction(execbase, OFFSET, oldf)
    ENDIF
    Enable()
    printmsgs()   /* Make sure the port is empty */
    DeleteMsgPort(port)
  ENDIF
ENDPROC

/* Nicely (?) print the messages out... */
PROC printmsgs()
  DEF msg:PTR TO mymsg
  WHILE msg:=GetMsg(port)
    WriteF('Task \l\s[25] wants \r\s[20]\n', msg.t, msg.s)
    /* Not really necessary to ReplyMsg() in this example */
    ReplyMsg(msg)
    DisposeLink(msg.t)
    DisposeLink(msg.s)
    Dispose(msg)
  ENDWHILE
ENDPROC

/* Send a message to the patching process */
PROC sendmsg()
  DEF m:PTR TO mymsg, s, tsk:tc, l:ln
  MOVE.L A1, s
  m:=New(SIZEOF mymsg) /* Allocate a new message */
  IF s
    m.s:=String(StrLen(s))
    StrCopy(m.s,s,ALL)
  ELSE
    m.s:='*unnamed library*'
  ENDIF
  tsk:=FindTask(NIL)   /* Find out who we are */
  m.t:=NIL
  IF tsk
    l:=tsk.ln
    IF l AND l.name
      m.t:=String(StrLen(l.name))
      StrCopy(m.t, l.name, ALL)
    ENDIF
  ENDIF
  IF m.t=NIL
    m.t:='*unnamed task*'
  ENDIF
  PutMsg(port, m)
ENDPROC

/* Place to store A4 register */
store:  LONG 0

/* The new routine which will replace the original library function */
newf:
  MOVEM.L D0-D7/A0-A6, -(A7)
  LEA store(PC), A0
  MOVE.L (A0), A4 /* Reinstate the A4 register so we can use E code */
  sendmsg()
  MOVEM.L (A7)+, D0-D7/A0-A6
patch:
  JMP $0
/* Yukky patch to the JMP code... */

----------------------  CUT HERE ------------------------------------------

---
   _____  _
     /   / |    /  /
    /   /__/   /__/      Jason R. Hulance
   /   /\     /  /   <[e-mail]>
|_/ . /  \ . /  / .
From crash!aston.ac.uk!sun.aston.ac.uk!nichowlw Mon, 10 Jan 94 03:41:46 PST
Received: by bkhouse.cts.com (V1.16/Amiga)
    id AA00000; Mon, 10 Jan 94 03:41:46 PST
Received: from sun2.nsfnet-relay.ac.uk by crash.cts.com with smtp
    (Smail3.1.28.1 #18) id m0pJKyO-0000VQC; Mon, 10 Jan 94 03:39 PST
Received: from denmark by email.aston.ac.uk with SMTP (PP)
          id <[e-mail]>; Mon, 10 Jan 1994 11:37:24 +0000
Via: uk.ac.aston; Mon, 10 Jan 1994 11:38:52 +0000
Date: Mon, 10 Jan 94 11:38:16 GMT
Message-Id: <[e-mail]>
X-Sun-Charset: US-ASCII
content-length: 61
From: nichowlw <[e-mail]>
To: [e-mail]
Subject: Unsubscribe

Please Unsubscribe me from the AmigaE mailing list.

Thanks